
# shapedrf2

This command generates an RF pulse at the current transmit frequency, which can be modulated in amplitude and phase. It also includes a gate pulse which is used to control an RF amplifier. This version replaces the single pulse version of shapedrf, the latter not being available on FX3 based Spinsolves.



*Applicability*

*DSP/FX3*

*Syntax*

shapedrf2(channel, ampPhaseTable, phaseOffset, tableSize, stepTime)

channel ........ 1 for channel 1 (Proton)

2 for channel 2 (X-Channel)

ampPhaseTable .. the name of table which controls the amplitude and phase during the generation of the shaped pulse. It has the form “tx” where x is an integer greater than 0. The table should contain interleaved amplitude and phase values. The amplitude values should be positive with a minimum value of 0 and a maximum of 16383. Use the command ucsRun:convertTxGain() to convert the amplitude in dB to one in this linear range. The phase values should contain positive integers with a minimum value of 0 and a maximum of 65535. This corresponds to phase shifts between 0 and 359.995 degrees.

phaseOffset ... the name of the parameter which controls the RF pulse phase relative to the system clock. It has the form “px” where x is an integer greater than 0. Phase values in the phase cycle table can be 0,1,2,3 corresponding to x, y, -x, –y (0, 90, 180, 270 degrees). Typically this is used to implement phase cycling. Fractional numbers can also be applied to implement other phases between 0 and 360 (0-4). The phase can also be supplied as a positive 16 bit integer in which case the parameter name has the form “nx” where x is an integer greater than 0. Constants can also be used.

tableSize ...... the name of the parameter which controls the number of values in each of the amplitude and phase subtables (both should have the same number of entries). It has the form “nx” where x is an integer greater than 0 or a constant can be supplied.

stepTime ....... the name of the parameter which controls the duration of each amplitude step.  It has the form “dx” where x is an integer greater than 0 or a constant can be used.

*Notes:*

1. The pulse generated by this command has a length which includes a fixed delay called the pulse gate overhead (pgo). This delay is used to set up the RF gate – a signal sent to the high powered amplifier to switch on the DC biasing before the RF pulse is actually sent. You should account for this delay when writing the relationships list described above (the predefined variable “pgo” (pulse gate overhead) can be used. The pgo on the Spinsolve is normally set to 5 s.

1. There are a maximum number of amplitude steps available determined by the amount of DSP or FX3 memory available. The total for all amplitude and phase tables must be less than 128 k values on a DSP Spinsolve and 512 k on the FX3 (but < 64 k per table).

1. The stepTime value may range from 2 s to 327,670 s. **Beware**: values below 2s can cause the RF to switch on for very long times.

1. Potentially the shaped RF pulse could have a large amplitude and last for a long time – the combination of these situation could damage a high-powered RF amplifier or probe. Always take care when setting the amplitude and setTime values. Place limits where possible.
2. To update the shaped RF pulse between scans requires resending the tables to the DSP however the phaseOffset parameter can be applied using a phase cycle table to adjust the phase by a constant amount based on the scan number.
3. In addition to the pgo delay at the beginning of the command it takes 0.35 s (DSP)/ 2 s (FX3) for the command to finish before another command can be given. On DSP systems you should always include (at least) a 1 us delay after this command before issuing another RF pulse.
4. The total duration (in s) of this command will be pgo + tableSize\*stepTime + 0.35/2. (DSP/FX3)

*Example pulse sequence: (PSExamples\ShapeRF2Test)*

############################################################

#

# Generates a pulse with a ramped shaped amplitude and a

# phase which jumps in the middle by 180 degrees

# using an interleaved table and the shapedrf2 command.

#

# For demonstration purposes only

#

# pulse - delay - shapedpulse - delay acq

#

############################################################

procedure(pulse\_program,dir,mode,pars)

# Expose parameters for FX3 implementation

if(nrArgs == 3)

assignlist(pars)

endif

# Interface description (name, label, ctrl, vartype)

interface = ["nucleus", "Nucleus", "tb", "readonly\_string";

"b1Freq", "Pulse frequency", "tb", "float";

"txMaxdB", "Pulse max amplitude (dB)", "tb", "float";

"nAmpSteps", "Amplitude steps", "tb", "integer";

"stepDur", "Table step length (us)", "tb", "pulselength";

"repTime", "Repetition time (ms)", "tb", "reptime"]

# Define the tab groups and their order

groups = ["Pulse\_sequence","Acquisition",

"Processing\_Std","Display\_Std","File\_Settings"]

# Relationships to determine remaining variable values

relationships = ["nDataPnts = nrPnts",

"b1Freq1H = b1Freq",

"a1 = 0",

"aMax = gFX3->convertAmplitude(txMaxdB)",

"ampSweep1 = linspace(0,aMax,nAmpSteps/2)",

"ampSweep2 = linspace(aMax,0,nAmpSteps/2)",

"phSweep1 = matrix(nAmpSteps/2)",

"phSweep2 = matrix(nAmpSteps/2)+32768",

"ampSweep = join(ampSweep2,ampSweep1)",

"phSweep = join(phSweep1,phSweep2)",

"tAmpPhase = gFX3->interleaveTables(ampSweep,phSweep)",

"nTabSz = size(tAmpPhase)/2",

"dTabStep = stepDur",

"totPnts = nrPnts",

"totTime = acqTime"]

# These parameters will be changed between experiments

variables = [""]

# Pulse sequence

initpp(dir)

pulse(1,a1,p1,10) # Generate a pulse for scope triggering

delay(10)

shapedrf2(1,tAmpPhase,p2,nTabSz,dTabStep) # Shaped amplitude/phase pulse

delay(10) # Pulse - acquire delay

acquire("overwrite",nDataPnts) # Acquire FID

parList = endpp() # Combine commands and return parameter list

# Phase cycle list

phaseList = [0,0,0,0; # p1 : Trigger phase

0,1,2,3; # p2 : Shaped phase

0,0,0,0] # pA : Acquire phase

endproc(parList,groups,interface,relationships,variables,null,phaseList)

The shaped pulse is generated in the relationship table and consists of two linear ramps the first ramping down and the second ramping up. The phase is zero for the first ramp and 180 degrees for the second.

Note the line defining tAmpPhase – this calls a procedure which interleaves the amplitude and phase tables into one.

*Test parameters*

B1Freq = 2 MHz, maximum amplitude 0 dB.

10 steps in shaped pulse.

Table step length = 4 s => total duration 40 s.

Transceiver channel 1 output, showing shaped RF pulse.

A screen shot of a graph

Description automatically generated